26.02.14 - Standalone EXE Linker released download link [1MB]
23.12.13 - FPW 2.6.1 runtime ESL released download link [1MB]
individual features are available
on request

FoxPro for Windows 2.6.1 (modded)

What is new in FoxPro for Windows 2.6.1

@ ... TO draws lines to arbitrary direction with unlimited pen width and raster opmodes (INVERT, XOR, MERGE ... )

Greatly improves FoxPro's ability to serve as a frontend graphing tool for scientific, financial and educational purposes.
Combined with strong database support makes FPW 2.6.1 a true all-in-one solution.

STYLE "/" activates slanted lines drawing
STYLE "T", "U", "V" ... "Z" selects raster opmode
Implemented natively, no external FLL libraries or WinAPI calls required.

code sample (test_01.prg):

      modi wind screen title "Microsoft "+VERSION() font 'Tahoma',8 style 'T'
      clear
      
      @ 1,60 fill to 16,64 color RGB(0,0,0,255,255,0)
      @ 1,64 fill to 16,68 color RGB(0,0,0,255, 96,0)
      
      mode = "T Transp    U Invert    V BackRGB   W NotPEN    X NotDEST   Y NotMERGE  Z MERGE!    "
      ROP2 = "COPYPEN     XORPEN      asis        NOTCOPYPEN  NOTMERGEPEN NOTXORPEN   MASKPEN     "
      
      @ 0, 72 say "Pen STYLES:" style "U"
      @ 0, 87 say "/ - slanted"

      FOR i=1 to 7
      @ i*2,4   to i*2,52    PEN 1,1
      @ 2,i*8-4 to  14,i*8-4 PEN 1,1
      @ i*2,58   to i*2,70   PEN 16   STYLE subs(mode,i*12-11,1) color RGB(160,240,128,0,0,0)
        if i=2
        @ i*2+0.5,59 to i*2+0.5,71 PEN 16   STYLE subs(mode,i*12-11,1)  color G+/R*
        @ i*2+1,71   say  "<-- 2nd call restores back !" font 'Tahoma',7  color B
        endif
      @ i*2,72  say subs(mode,i*12-11,12)
      @ i*2,86  say "("+TRIM(subs(ROP2,i*12-11,12))+")"
      ENDFOR

      SET DECIMALS to 2
      delta=60
      
      FOR i=0 to 360-delta step delta
      x1=SIN(DTOR(i))*4 + 8
      y1=i/8 + 5
      x2=SIN(DTOR(i+delta))*4 + 8
      y2=(i+delta)/8 + 5
         if "2.6.1" $ VERS() .or. (x2 >= x1 .and. y2 >= y1)
         @ x1+0.5,y1+1 to x2+0.5,y2+1 STYLE "/Z" PEN 5  color N+
         @ x1,    y1   to x2,    y2   STYLE "/"  PEN 5  color RGB(255,64,0,0,0,0)
         endif
      ENDFOR

POPUPs, COMBOs and LISTs may include user defined pictures, FocusRect removed, Up/Dn arrows bitmaps changed

This feature has been uncovered after 20 years of ignorance.
Pictures width and height aren't limited.
Great for implementing user friendly menus, treeview lists and comboboxes with hint icons.

At the end of the PROMPT clause place formatting option '\:' followed by FILENAME.BMP (relative path not available by now)
Implemented natively, no external FLL libraries or WinAPI calls required.

code sample (test_02.prg):

      modi wind screen title "Microsoft "+VERSION() font 'Tahoma',8
      clear

      store 1 to m.P, m.Y

      @ 1,2 get m.P func '^' pict ' Android \:AND.BMP;'     +;
                                  '  iOS \:APP.BMP;'        +;
                                  '   BlackBerry \:BLA.BMP;'+;
                                  '    Windows \:WIN.BMP'    ;
                                       font 'Tahoma',10  color ,,R/W*,,,W+/R

      define popup TreeView from 1,20 title "fin.period" color ,/W*,B/,,,W+/B  && 2.txt/3.frame/6.hi

         define bar  1 of TreeView prompt " 2010      \:x.bmp"
         define bar  2 of TreeView prompt " 2011      \:x.bmp"
         define bar  3 of TreeView prompt " 2012      \:x.bmp"
         define bar  4 of TreeView prompt " 2013      \:o.bmp"
         define bar  5 of TreeView prompt " 1 quarter \:lo.bmp"
         define bar  6 of TreeView prompt " jan       \:llF.bmp"
         define bar  7 of TreeView prompt " feb       \:llF.bmp"
         define bar  8 of TreeView prompt " mar       \:llL_.bmp"
         define bar  9 of TreeView prompt " 2 quarter \:lo.bmp"
         define bar 10 of TreeView prompt " apr       \:llF.bmp"
         define bar 11 of TreeView prompt " may       \:llF.bmp"
         define bar 12 of TreeView prompt " jun       \:llL_.bmp"
         define bar 13 of TreeView prompt " 3 quarter \:lo.bmp"
         define bar 14 of TreeView prompt " jul       \:llF.bmp"
         define bar 15 of TreeView prompt " aug       \:llF.bmp"
         define bar 16 of TreeView prompt " sep       \:llL_.bmp"

      @ 1,32 get m.Y POPUP TreeView size 15,25

      read cycle

@ ... BOX is capable to display 3D frames with standard, sunken, flat, outlined and frameonly styles

Featured FORMs and MESSAGEBOXes could be drawn with few lines of code.
Ideal for building full screen layouts, outline @ GET/EDIT input fields and so on.
VFP's GRIDs behaviour could be easily reproduced with additional inkey(), SCROLL and @TO...STYLE "U" commands.

An updated @...BOX command syntax:
@ row,col,rowZ,colZ BOX [CHR(style)]
where single character style argument is:

[] - 3D-normal (BTNFACE #D4D0C8 fill color used)
CHR(0) - flat
CHR(1) - 3D-pressed
CHR(2) - 3D-normal (same as with no args)
CHR(3) - 3D-inverted
CHR(64+...) - focused (outlined)
CHR(128+..) - frame only (inners remain untouched)
Implemented natively, no external FLL libraries or WinAPI calls required.

code sample (test_03.prg):

      modi wind screen title "Microsoft "+VERSION() font 'Tahoma',8 style 'T'
      clear
      
      #define FLAT   CHR(0)
      #define SUNKEN CHR(1)
      #define NORMAL CHR(2)
      #define INVERT CHR(3)
      #define ACTIVE CHR(2+64)
      #define FRAME  CHR(2+128)
      #define FRAMEX CHR(3+128)

      if "2.6.1" $ VERS()
      @ 0.5,0 fill to 13.5,78 color /W
      endif
      
      @  1,2, 2.5,17 box 
      @  3,2, 4.5,17 box FLAT  
      @  5,2, 6.5,17 box INVERT
      @  7,2, 8.5,17 box ACTIVE
      @  9,2,  13,17 box FRAME
      
      grid_X =2
      grid_Y =23
      grid_Xz=10
      grid_Yz=74
      head="col.1   : 7|col.2   :10|col.3   :30|...     : 4|"
      line=+4
      
      dX=1/FONT(1)
      dY=1/FONT(6)
      
      @ 1,21,13,76 box
      @ grid_X,   grid_Y fill to grid_Xz,   grid_Yz    color /GR*
      @ grid_X-dX,grid_Y-dY,     grid_Xz+dX,grid_Yz+dY box FRAMEX
      @ grid_Xz+0.5,grid_Y,grid_Xz+0.5+2*dX,grid_Yz    box INVERT
      @ grid_Xz+1,grid_Yz-30 fill to grid_Xz+2.5,grid_Yz-15 color /G*
      @ grid_Xz+1,grid_Yz-14 fill to grid_Xz+2.5,grid_Yz    color /R*
      @ grid_Xz+1,grid_Yz-30,grid_Xz+2.5,grid_Yz-15    box FRAME
      @ grid_Xz+1,grid_Yz-14,grid_Xz+2.5,grid_Yz       box FRAME
      
      SET DECIMALS to 5
      =RAND(-1)
      Y=grid_Y
      
      FOR i=1 to LEN(head)/12
      wh=VAL(subs(head,i*12-2,2))
      @ grid_X,Y,grid_X+1,Y+wh box
      @ grid_X,Y+1 say TRIM(subs(head,i*12-11,8))
      @ grid_X+1,MIN(Y,grid_Yz)-dY to IIF(Y>grid_Y,grid_Xz,grid_X+1),MIN(Y,grid_Yz)-dY color N+
         FOR j=grid_X+1 to grid_Xz-1
         DO CASE
         CASE i=1
            @ j,Y+1 say str(j-2,3)
         CASE i=2
            @ j,Y+1 say subs('January FebruaryMarch   April   May     June    July    August  ',(j-2)*8-7,8)
         CASE i=3
            @ j,Y+1 say LTRIM(str(100000*RAND(),7))
         OTHERWISE
            @ j-dX,grid_Y to j-dX,IIF(j>grid_X+1,grid_Yz,grid_Y) color N+
            @ j,Y+1 say subs('+ ',j%2+1,1)
         ENDCASE
         ENDFOR
      Y=Y+wh
      ENDFOR

      @ grid_X+line,grid_Y to grid_X+line,grid_Yz pen FONT(1) STYLE 'U'  && inverts GRID's cur.line !

Ubuntu 'Ambiance' theme applied to user defined TITLE/HALFHEIGHT windows

I made my choice in favor of Linux based distro theme. Two great products meets together here...
Because of ...you know... "2.6.1" reminds me one of the well known stable Linux kernel version.

Ask Hetzenwerke if you want to run FoxPro under SCO UNIX / Linux OS.
Implemented natively, no external FLL libraries or WinAPI calls required.

code sample (test_04.prg):

      modi wind screen title "Microsoft "+VERSION()
      
      defi wind MSG_1 title "OSX/Ubuntu theme" ZOOM MINI GROW FLOAT from 1,2 to 10,58 ;
                                 color N/N*
      ACTI WIND MSG_1
      defi wind MSG_2 in MSG_1   title "Lemon theme" ZOOM MINI GROW  from 1,4 to  7,54 ;
                                 color N/G*,,,G/G*
      ACTI WIND MSG_2
      defi wind MSG_3 in MSG_2   title "Aqua  theme" ZOOM MINI GROW  from 1,4 to  4,48 ;
                                 color N/B*,,,B/B*
      ACTI WIND MSG_3
      
      =INKEY(0,'HM')
      
      release wind MSG_1, MSG_2, MSG_3
      
      ACTI WIND COMMAND

redesigned @ ... PUSH buttons keep requested width and may be filled with custom colors

Gives better control over PUSH buttons layout.
Color highlight may emphasize control's target action (yes/no, ins/del...).

Color pair #9 sets foreground/background colors of the PUSH button control.
Implemented natively, no external FLL libraries or WinAPI calls required.

code sample (test_05.prg):

      modi wind screen title "Microsoft "+VERSION()
      SET COLOR of SCHEME 1 to ,,,,,,,,N/R*

      m.What=1

      @ 0,0 fill to 13,19 color RGB(0,0,0,228,228,228)
      @  1,2 get m.What func "*  Left           ;     Center     ;          Right " size 2,15
      read cycle
      @  8,2 get m.What func "*  very large caption ; caption " color  ,,,,,,,,B/B* size 2,15
      show GETs

@ ... PUSH BMP buttons have images stretched, frame not visible when image background is not white

True image maps are available, popped frames and focus rects aren't visible anymore.

To reveal standart button 3D frame apply white surrounding frame on the image.

code sample (test_06.prg):

      modi wind screen title "Microsoft "+VERSION() font 'Tahoma',8
      SET COLOR of SCHEME 1 to ,,,,,,,,N/N*               && BTNTEXT/BTNFACE

      @ 0,0 fill to 8,44 color RGB(0,0,0,212,208,200)     && == N/N*

      m.What=1
      @ 1,2 get m.What func "*B APPLE.BMP"   size   3,40  && 104x66 pix
      @ 5,2 get m.What func "*B NEWGUI.BMP"  size 1.8,40  && 196x23 pix
      show GETs

@ ... CHECK/RADIO controls always have transparent 3D style

Ugly looking 2D CHECK/RADIO controls were a shame of the standard FPW 2.6 engine.
Problem is solved from now on.
Leading/trailing spaces aren't removed from PUSH/POPUP/LIST/COMBO/CHECK/RADIO prompts, so treeview like menus and right aligned captions of controls are available.

code sample (test_07.prg):

      modi wind screen title "Microsoft "+VERSION()
      SET COLOR of SCHEME 1 to N/W
      clear

      Chkvar=1
      Option=' not trimmed '

      @ 1.5,2 to 7.5,30
      @ 2,3 get  Chkvar FUNC '*C' PICT ' checked 3D option '
      @ 4,3 get  Option           PICT '@*R       leading spaces ; not trimmed ;      anymore '
      read cycle

@ ... SPINNER and COMBO controls black frame removed
@ ... EDIT field not outlined anymore
SCROLLBARs polished

Makes control's appearance more predictable and less aggressive.
It is up to programmer to add / omit outlined frames (see @...BOX details).
Frameless controls can be seamlessly embedded into grids and likes.

code sample (test_08.prg):

      modi wind screen title "Microsoft "+VERSION()
      SET COLOR of SCHEME 1 to N/W
      clear

      store 1 to Spin,Pict
      txt = "Text string to be modified within the @EDIT rectangle..."

      ResID = ''
      FOR i=3 to 6
      ResID = ResID + ' FoxResID xA'+subs('  3456',i,1)+' \:0xA'+subs('  3456',i,1)+'.BMP;'
      ENDFOR
      ResID = LEFT(ResID,LEN(ResID)-1)

      @ 1,2    get Spin SPINNER  1,0,9999 pict "9999" style 'B'         color ,W+/B
      @ 1,10.5 EDIT txt SIZE 3,20 SCROLL  color ,N/GR*
      @ 5,2    get Pict func '^'          pict ResID  font  'Tahoma',10 color ,,N+/,,,W+/B,,,N/GR*
      read cycle

@ ... MENU and POPUP borders, headers and footers have 3D style by default, BTNFACE color RGB(212,208,200) used as default, frames color softened

Makes context menu POPUP creation a simple task, especially with @...MENU command.

Please note: 3D style ([border] DOUBLE) is set globally, so [border] SINGLE is no more available for common control objects.

code sample (test_09.prg):

      modi wind screen title "Microsoft "+VERSION()
      SET COLOR of SCHEME 1 to N/W*
      clear

      Declare MNU[5]
      MNU[1]="        array "
      MNU[2]="      based   "
      MNU[3]="    menu      "
      MNU[4]="  contents    "
      MNU[5]="...           "

      define POPUP FileList from 1,20 to 15,40 prompt FILES like "*.*" title "Files:"

      set border to DOUBLE
      X=0

      @ 1,2 MENU MNU, ALEN(MNU) title "-=-"
      read menu to X

      acti POPUP FileList

@ ... FILL no more requires preceding @ CLEAR to succeed

@ FILL works now as it was stated in the documentation and by the same way as in the previous FoxPro Win/DOS versions.
I know, everyone use @ TO with inner FILL option as a replacement, but why settle for workarounds ?

code sample (test_10.prg):

      modi wind screen title "Microsoft "+VERSION()
      SET COLOR of SCHEME 1 to N/W*

      clear
      @ 1,2   fill to 4,26  color /N
      @ 2,4   fill to 4,26  color /N*
      @ 3,6   fill to 4,26  color /W

WAIT WINDOW tries to look like floating ToolTip reminder

As simple as it could be...

code sample (test_11.prg):

      modi wind screen title "Microsoft "+VERSION()

      WAIT WINDOW "This is a warning"+CHR(13)+"message..."

RGB values behind standard COLOR PAIRs softened

Color pairs softened enough to be used as is in the most cases without RGB() replacement calls.

Technical details:
- values N/N [x00] weren't changed
- normal values F/B [x00,x80] raised to [x60,xE0] correspondingly
- high values F+/B* [x00 < ... < xFF] raised to [xE0]
- special case N+/N* [x3F] converted to fixed RGB[xD4,xD0,xC8] Win BTNFACE value

code sample (test_12.prg):

      modi wind screen title "Microsoft "+VERSION()
      clear
      
      PenB=14
      PenF=IIF('2.6.1' $ VERSION(), 8,6) font 'Tahoma',8
      
      @ 2,2 say "Fore: X,X+"  font 'Courier New',8 style 'B'
      
      @ 1,18 to 4,25 PEN PenB color R
      @ 2,20 to 3,23 PEN PenF color R+
      @ 1,25 to 4,32 PEN PenB color G
      @ 2,27 to 3,30 PEN PenF color G+
      @ 1,32 to 4,39 PEN PenB color B
      @ 2,34 to 3,37 PEN PenF color B+
      @ 1,39 to 4,46 PEN PenB color GR
      @ 2,41 to 3,44 PEN PenF color GR+
      @ 1,46 to 4,53 PEN PenB color BG
      @ 2,48 to 3,51 PEN PenF color BG+
      @ 1,53 to 4,60 PEN PenB color RB
      @ 2,55 to 3,58 PEN PenF color RB+
      @ 1,60 to 4,67 PEN PenB color W
      @ 2,62 to 3,65 PEN PenF color W+
      @ 1,67 to 4,74 PEN PenB color N
      @ 2,69 to 3,72 PEN PenF color N+
      
      @ 5,2 say "Back: X,X*"  font 'Courier New',8 style 'B'
      
      @ 4,18 fill to 7,25 color /R
      @ 5,20 fill to 6,23 color /R*
      @ 4,25 fill to 7,32 color /G
      @ 5,27 fill to 6,30 color /G*
      @ 4,32 fill to 7,39 color /B
      @ 5,34 fill to 6,37 color /B*
      @ 4,39 fill to 7,46 color /GR
      @ 5,41 fill to 6,44 color /GR*
      @ 4,46 fill to 7,53 color /BG
      @ 5,48 fill to 6,51 color /BG*
      @ 4,53 fill to 7,60 color /RB
      @ 5,55 fill to 6,58 color /RB*
      @ 4,60 fill to 7,67 color /W
      @ 5,62 fill to 6,65 color /W*
      @ 4,67 fill to 7,74 color /N
      @ 5,69 fill to 6,72 color /N*
      
      @ 4,18 to 4,74 color W+

default Window/DIALOGs font set to 'MS Shell Dlg'/'Tahoma',8,
enlarged COMMAND window relocated to bottom right and got 'Courier',10 font

Some features available in IDE environment only.

Some color SCHEMEs were unlocked (undocumented):
4 - user defined MENUs/POPUPs
5 - COMMAND and Editors windows
13 - SYSMENU
14 - DIALOGs and BROWSE windows

code sample (test_13.prg):

      modi wind screen title "Microsoft "+VERSION()
      clear
      
      set color of scheme 13 to B+/B,BG+/B,N/B,,,N/R*
      set color of scheme 14 to N/G*,B/W* ,,,,,,,N/B*
      move wind COMMAND to 1,80
      
      ? SYS(2017)
      SCROLL 0,0,WROW()-2,WCOL()-2,25,-45
      @ 0,35 say WFONT(1)+str(WFONT(2),2)

      KEYBOARD '{Alt+F}'
      WAIT WINDOW "Press any key..."

      ? GETFILE()

[Ctrl+]MOUSEWHEEL captured and translated into standard [Up]/Dn keys
DOS-437 and DOS-850 keyboard maps replaced with cyrillic DOS-866 and WIN-1251
MEMLIMIT=80,4096,16384 / MVCOUNT=2048 are set as default values

Handy mouseWheel navigation is enabled for all MENU / BROWSE / EDITORs windows.
Because of WinAPI 16bit restrictions, zDelta=Up/Dn (wParam highword) part of the WM_MOUSEWHEEL message gets zeroed by OS.
To translate MouseWheel into upward keycode, user should keep CTRL key pressed.

Russian users can take advantage of the Win-1251 and DOS-866 keyboard maps embedded.
The presence of the FOXPRO.INT isn't required anymore.

With MEMLIMIT and MVCOUNT values preset there is less to be occupied with CONFIG.FPW settings.

Key Features

Lines
Menus
Windows
Boxes
Controls
Colors
Misc

Support

EXE-linker new
FAQ

todo List

EXE Linker

Standalone EXE make utility

Standalone EXE make utility itself has been made by merging FOXW2601.ESL Support Library 2.6.1
and precompiled compact LINKER.EXE into a single executable.

Creation dialog is capable to set additional properties of the output distribution file:

   user selected icon (32x32, 16 colors)
   normal / minimized / maximized startup mode
   registration splash logo removal
   readonly attributes for network deployment
Download link (with source code): FPW 2.6.1 Linker [1MB]

Frequently Acked Questions

Questions & Answers

Q: I've copied FOXW2601.ESL to the working directory, but nothing extraordinary happened with my EXEs at runtime.

A: Rename 'FOXW2601.ESL' to 'FOXW2600.ESL'.
This is a default runtime support library name used by compiled FoxPro EXE modules.

Q:

A: